编写DLL扩展ArcMap功能

ArcGIS不仅仅是一个可直接使用的GIS程序集，也是一套完整的功能框架，它提供了多种方式可以让用户扩展功能，我们知道，这种扩展方式有三种，VBA，DLL和控件开发，前两者与框架是紧密相关的。对于VBA，许多书中已经介绍的非常清楚，而使用MapControl控件，也是我的书的重点内容。使用DLL来扩展功能，则是见于一些零散的文档中。

作为一个应用程序框架，以ArcMap为例，它必然提供了许多接口让用户可以实现，从而达到扩展的功能。以产生一个浮动窗口为例，即DockableWindow，我们知道，如果要产生这样一个对象，必须使用IDockableWindowDef接口；产生这样一个窗体后，我们希望是使用一个按钮的方式来打开这个窗口，这又必须使用ICommand接口才行，而这个按钮，还需要与已经存在的按钮在格调上一致。

下面是整个过程：

1. 启动VB6，然后点击ActiveX dll选项，在工程中会出现一个class1.cls的类模块（我更喜欢使用VB6来写DLL，因为它对DLL的UID设置和Outbound Interface的实现都比较方便）
2. 将工程名改为DockableWindow，它将来将作为一个类库名出现。
3. 引入必须的类库，如ArcMapUI、FrameWork、System、SystemUI和Carto
4. 引入资源文件，点选菜单“Add －Ins”下的“Add －in Manager”，在弹出的对话框的列表框中选择“VB Resource (RES) Editor”，单击“OK“后退出对话框。这样在“Tools”菜单栏中就有一项“Resource Editor”了。打开这个工具然后导入一个已经存在的位图文件，这个文件被加入后的编号为101，我们将在ICommand中使用它。
5. 添加一个窗体，改名为frmDockWin，在窗体上添加一个listbox控件，改名为lstSelCount
6. 将class1改名为cmdDockWin，然后键入如下代码：

Implements ICommand '必须实现该接口才能成为一个按钮

Private m_pApp As IApplication
Private m_pDockWinMgr As IDockableWindowManager
Private m_pDockWin As IDockableWindow
Private m_pBitmap As IPictureDisp

Private Sub Class_Initialize()
'使用我们刚才新建的资源文件，0为位图类型
Set m_pBitmap = LoadResPicture(101, 0)
End Sub

Private Property Get ICommand_Bitmap() As esriSystem.OLE_HANDLE
'按钮的图标为m_pBitmap对象，即我们引入的那张位图
ICommand_Bitmap = m_pBitmap
End Property

Private Property Get ICommand_Caption() As String
ICommand_Caption = "SelCount Dockable Window"
End Property

Private Property Get ICommand_Category() As String
'该按钮会出现的目录是在Developer Samples，当我们打开Customize时，在Commands中会看到两栏，左边就是目录，右边是目录中可用的命令
ICommand_Category = "Developer Samples"
End Property

Private Property Get ICommand_Checked() As Boolean
ICommand_Checked = m_pDockWin.IsVisible
End Property

Private Property Get ICommand_Enabled() As Boolean
ICommand_Enabled = True
End Property

Private Property Get ICommand_HelpContextID() As Long

End Property

Private Property Get ICommand_HelpFile() As String

End Property

Private Property Get ICommand_Message() As String
ICommand_Message = "Display the selection count dockable window"
End Property

Private Property Get ICommand_Name() As String
ICommand_Name = "DeveloperSamples_SelCountDockableWindow"
End Property

Private Sub ICommand_OnClick()
m_pDockWin.Show Not m_pDockWin.IsVisible
End Sub

Private Sub ICommand_OnCreate(ByVal hook As Object)
'按钮初始化，从hook中引入Application对象，新建浮动窗体对象m_pDockWin
Set m_pApp = hook
Set m_pDockWinMgr = hook 'QI for IDockableWindowManager
' Get a reference to the selection count dockable window
Dim u As New UID
u.Value = "DockableWindow.DockWin"
Set m_pDockWin = m_pDockWinMgr.GetDockableWindow(u)
End Sub

Private Property Get ICommand_Tooltip() As String
ICommand_Tooltip = "Selection Count"
End Property

7. 添加一个类模块，改名为DockWin，键入如下代码

Implements IDockableWindowDef

Private m_pApp As IApplication
Private m_pMXDoc As IMxDocument
Private WithEvents m_pDocEvent As MxDocument ' Listen for the MxDocument events
Private WithEvents m_pMapEvent As Map ' Listen for the Map events
Private WithEvents m_pLayoutEvent As PageLayout ' Listen for the PageLayout events

Private Property Get IDockableWindowDef_Caption() As String
IDockableWindowDef_Caption = "Selected Features Count"
End Property

Private Property Get IDockableWindowDef_ChildHWND() As esriSystem.OLE_HANDLE
'它需要使用到frmdockwin窗体的listbox控件来显示数据
IDockableWindowDef_ChildHWND = frmDockWin.lstSelCount.hWnd
End Property

Private Property Get IDockableWindowDef_Name() As String
IDockableWindowDef_Name = "Selection Count"
End Property

Private Sub IDockableWindowDef_OnCreate(ByVal hook As Object)
Set m_pApp = hook
'Start listening to the MxDocument events
If Not m_pDocEvent Is m_pApp.Document Then
Set m_pDocEvent = m_pApp.Document
End If
Set m_pMXDoc = m_pApp.Document
If Not m_pMapEvent Is m_pMXDoc.FocusMap Then
Set m_pMapEvent = m_pMXDoc.FocusMap
End If
If Not m_pLayoutEvent Is m_pMXDoc.PageLayout Then
Set m_pLayoutEvent = m_pMXDoc.PageLayout
End If
End Sub

Private Sub IDockableWindowDef_OnDestroy()
Set m_pMapEvent = Nothing
Set m_pLayoutEvent = Nothing
Set m_pMXDoc = Nothing
Set m_pApp = Nothing
End Sub

Private Property Get IDockableWindowDef_UserData() As Variant

End Property

Private Function m_pDocEvent_MapsChanged() As Boolean
' Clear the list box and reset the reference to the map when a new dataframe
' is added to the document.
frmDockWin.lstSelCount.Clear
If Not m_pMapEvent Is m_pMXDoc.FocusMap Then
Set m_pMapEvent = m_pMXDoc.FocusMap
End If
End Function

Private Function m_pDocEvent_NewDocument() As Boolean
' Clear the list box and reset the reference to the map and pagelayout when
' a new document is created.
frmDockWin.lstSelCount.Clear
If Not m_pMapEvent Is m_pMXDoc.FocusMap Then
Set m_pMapEvent = m_pMXDoc.FocusMap
End If
If Not m_pLayoutEvent Is m_pMXDoc.PageLayout Then
Set m_pLayoutEvent = m_pMXDoc.PageLayout
End If
End Function

Private Function m_pDocEvent_OpenDocument() As Boolean
' Clear the list box and reset the reference to the map and pagelayout when
' another document is opened.
frmDockWin.lstSelCount.Clear
If Not m_pMapEvent Is m_pMXDoc.FocusMap Then
Set m_pMapEvent = m_pMXDoc.FocusMap
End If
If Not m_pLayoutEvent Is m_pMXDoc.PageLayout Then
Set m_pLayoutEvent = m_pMXDoc.PageLayout
End If
End Function

Private Sub m_pLayoutEvent_FocusMapChanged()
' Clear the list box and reset the reference to the map when
' a different map (dataframe) is made active.
frmDockWin.lstSelCount.Clear
If Not m_pMapEvent Is m_pMXDoc.FocusMap Then
Set m_pMapEvent = m_pMXDoc.FocusMap
End If
End Sub

Private Sub m_pMapEvent_SelectionChanged()
' When the selection changes is the map, update the contents of the listbox
Dim pMap As IMap
Dim i As Integer
Dim pFLayer As IFeatureLayer
Dim pSel As IFeatureSelection
Set pMap = m_pMapEvent

frmDockWin.lstSelCount.Clear

'Loop through the layers in the map and add the layer's name and
'selection count to the list box
For i = 0 To pMap.LayerCount - 1
If TypeOf pMap.Layer(i) Is IFeatureSelection Then
Set pFLayer = pMap.Layer(i)
Set pSel = pFLayer
frmDockWin.lstSelCount.AddItem pFLayer.Name & ": " & pSel.SelectionSet.Count
End If
Next
End Sub

8. 代码编写完毕，点击文件——生成DockableWindow.dll按钮，生成一个DLL文件（如果开始没有保存，此时将要求保存）
9. 打开工程——DockableWindow属性——部件，将“版本兼容”设置为“二进制兼容”，保存工程。
10. 打开ArcGIS的Component Category Manager，分别将dll中的两个类导入不同的组件目录，cmdDockWin导入ESRI Mx Comands目录，DockWin导入ESRI Mx Dockable Windows目录
11. 打开ArcGIS程序，在Customize中查看是否存在“Developer Samples”目录，将目录中的命令拖到任何一个命令栏上，点击后，即可出现一个浮动窗体。
    

Related Items

• 要素闪烁的另一种方法

• 复制要素类

• IdentifyDialog类的简单示例

• 使用GxDialog载入一个要素类或要素数据集

• 地图裁减程序

• 做了一个土地评价

• 书籍纰漏错误意见

• 书籍封面

• 书稿的推荐词

• Geodatabase中的QueryDef对象